Как скопировать как путь без кавычек и в формате URI файла?

При использовании встроенного параметра контекстного меню «Копировать как путь» или Копировать путь Кнопка ленты, чтобы скопировать имена файлов в буфер обмена, вывод будет содержать кавычки для путей к именам файлов / папок, как показано ниже.

скопировать как путь без кавычек и в формате URI

Не нужны кавычки? Используйте метод сценария

В некоторых ситуациях вам не нужны кавычки, независимо от того, содержат ли имена файлов пробелы или нет. Для этого вы можете добавить свой собственный параметр «Копировать как путь», используя собственный скрипт, и получить к нему доступ из меню «Отправить».

Я сделал сценарий, который делает это, используя превосходный NirCmd, многоцелевой инструмент автоматизации командной строки. При желании сценарий также можно изменить, чтобы при необходимости копировать пути к файлам в формате URI.

Скопировать как Path Script

1. Загрузите NirCmd с Nirsoft.net и распакуйте NirCmd.exe в вашу папку Windows.

2. Загрузите Copy_as_Path.vbs (zip), разархивируйте и распакуйте файл Vbscript (.vbs).

3. Переместите скрипт в постоянное место, такое как C: \ Windows или в любое другое место.

4. Дважды щелкните скрипт, чтобы он автоматически добавлял ярлык в папку «Отправить». Вы должны сделать это только в первый раз.

Теперь выберите файлы / папки, нажмите «Отправить» и нажмите «Копировать как путь».

скопировать как путь без кавычек и в формате URI

Это копирует пути к файлам / папкам в буфер обмена без кавычек.

скопировать как путь без кавычек и в формате URI

Как скопировать пути в формате URI?

Вы можете скопировать пути к файлам в формате URI, как показано ниже.

file:///C:/Program%20Files/Common%20Files

Для этого отредактируйте файл скрипта (.vbs) с помощью Блокнота и измените следующую строку:

CopyAsURI = 0

как показано ниже:

CopyAsURI = 1

И сохраните файл скрипта.

скопировать как путь без кавычек и в формате URI

Выберите файлы / папки, нажмите «Отправить» и нажмите «Копировать как путь». Пути к файлам / папкам теперь будут копироваться в формате URI.

copyaspath-URI-5

Содержимое файла Vbscript

'Author      : Ramesh Srinivasan, Winhelponline.com
'Created     : on 25 August 2016
'Description : Copy as Path to Clipboard without quotes
'Description : Optionally copy file paths in File URI format
'Requirement : Uses NirCmd.exe from Nirsoft.net
Dim WshShell: Set WshShell = WScript.CreateObject("Wscript.Shell")
'To copy file names in URI format, change the following value to 1
Dim CopyAsURI
CopyAsURI = 1
If WScript.arguments.count = 0 Then
'Add script shortcut to "Send To" menu
strSendTo = WshShell.SpecialFolders("Appdata")
strSendTo = strSendTo & "\Microsoft\Windows\SendTo"
Set oShrtCut = WshShell.CreateShortcut(strSendTo + "\Copy as Path.lnk")
oShrtCut.IconLocation = "%Windir%\system32\imageres.dll,-5302"
oShrtCut.TargetPath = "%Windir%\System32\wscript.exe"
oShrtCut.Arguments = """" & WScript.ScriptFullName & """"
oShrtCut.Save
Else
Dim strAll
strAll = ""
If CopyAsURI = 1 Then
For Each args In WScript.Arguments
strPath = "file:///" & args
strPath = Replace(strPath,"\","/")
strPath = Replace(strPath," ","%20")
strAll = strAll & """" & strPath & """" & vbCrLf
Next
Else
For Each args In WScript.Arguments
strAll = strAll & """" & args & """" & vbCrLf
Next
End If
If Right(strAll, 2) = vbCrLf Then strAll = Left(strAll, Len(strAll) - 2)
sCmd = "nircmd.exe" & " clipboard set " & strAll
WshShell.Run sCmd,0,0
Set WshShell = Nothing
End If

Статьи по Теме

  1. В Windows 10 встроенную опцию «Копировать как путь» можно настроить так, чтобы она отображалась без нажатия клавиши SHIFT. См .: Показать «Копировать как путь» всегда в контекстном меню без клавиши Shift в Windows 10
  2. Опция «Копировать как путь» существует начиная с Windows Vista, и здесь есть краткий обзор. Использование команды «Копировать как путь» для копирования пути к файлу или папке в буфер обмена
  3. В этой статье есть аналогичный скрипт, который поможет вам скопировать пути к файлам в формате UNC. Как отправить файл по электронной почте Путь к получателю почты с помощью меню «Отправить»?
  4. Эта статья «Меню правого клика« Копировать как путь »в Windows изначально была написана для Windows XP, но работает в любой версии Windows, хотя в последующих версиях Windows она вам не нужна.

Надеюсь, вы найдете эти сценарии полезными и продуктивными. Давай узнаем твои комментарии.

Ссылка на основную публикацию